Quick PC 61/Quick PC 61.iso/I386/WMS.CAB/NetworkSource.asp

Text File | 2003-02-21 | 29.5 KB | 822 lines

<%@ Language=VBScript CODEPAGE=65001 %>
<!--#include file="include/wmsLocStrings.inc"-->
<!--#include file="include/wmsServerHash.inc"-->
<!--#include file="include/wmsPlugins.inc"-->
<!--#include file="include/wmsHeader.inc"-->
<!--#include file="include/wmsPageBanner.inc"-->
<!--#include file="include/wmsError.inc"-->
<!--#include file="plugin_loading.inc"-->
<%
'+-------------------------------------------------------------------------
'
'  Microsoft Windows Media
'  Copyright (C) Microsoft Corporation. All rights reserved.
'
'  File:       NetworkSource.asp
'
'  Contents:
'
'--------------------------------------------------------------------------

ConnectToPlugin
ConnectToPluginAdmin

on error goto 0

Dim g_bError
Dim dwTabIndex

Dim bUdpEnabled
Dim bUseUdpPorts
Dim strUdpPortRange
Dim bTcpEnabled
Dim dwNumProtocols

Const WMS_PROXY_SETTING_NONE      = 0
Const WMS_PROXY_SETTING_MANUAL    = 1
Const WMS_PROXY_SETTING_AUTO      = 2
Const WMS_PROXY_SETTING_BROWSER   = 3        ' Only valid for HTTP

dwTabIndex = 0
g_bError = FALSE

bUdpEnabled = FALSE
bUseUdpPorts = FALSE
strUdpPortRange = GetPostOrQsVal( "portRange" )
bTcpEnabled = FALSE

if( FALSE = IsEmpty( g_objPluginAdmin ) ) then
    dwNumProtocols = g_objPluginAdmin.NumProtocolsSupported
else
    dwNumProtocols = 0
end if

Dim strOp
strOp = GetFormStr( "submit" )
if( 0 < Len( strOp ) ) then

    on error goto 0
    Err.Clear
    Session( "ErrorNumber" ) = 0
    err.number = 0
    g_bError = FALSE

    ' use a do-while-false structure to break out upon first error
    do
        if ( 0 = StrComp( "on", GetFormStr("useUDP"), vbTextCompare ) ) then
            if( FALSE = g_objPluginAdmin.UDPEnabled ) then
                g_objPluginAdmin.UDPEnabled = TRUE
                if( ErrorDetected( "UDP" ) ) then
                    err.description = RemoveDangerousCharacters( L_FAILEDTOENABLEUDP_TEXT )
                    g_bError = TRUE
                    Exit Do
                end if
            end if

            if( "" <> GetFormStr("usePorts") ) then
                if( 0 = Len( strUdpPortRange ) ) then
                    g_objPluginAdmin.DeleteAllUDPPortRanges
                else
                    if( FALSE = SetRanges( strUdpPortRange ) ) then
                        if( ErrorDetected( "portRange" ) ) then
                            g_bError = TRUE
                            Exit Do
                        end if
                    end if
                end if
            else
                g_objPluginAdmin.DeleteAllUDPPortRanges
            end if
        else
            if( TRUE = g_objPluginAdmin.UDPEnabled ) then
                g_objPluginAdmin.UDPEnabled = FALSE
                if( ErrorDetected( "UDP" ) ) then
                    err.description = RemoveDangerousCharacters( L_FAILEDTODISABLEUDP_TEXT )
                    g_bError = TRUE
                    Exit Do
                end if
            end if
        end if

        if ( 0 = StrComp( "on", GetFormStr("useTCP"), vbTextCompare ) ) then
            if( FALSE = g_objPluginAdmin.TCPEnabled ) then
                g_objPluginAdmin.TCPEnabled = TRUE
                if( ErrorDetected( "TCP" ) ) then
                    err.description = RemoveDangerousCharacters( L_FAILEDTOENABLETCP_TEXT )
                    g_bError = TRUE
                    Exit Do
                end if
            end if

        else
            if( TRUE = g_objPluginAdmin.TCPEnabled ) then
                g_objPluginAdmin.TCPEnabled = FALSE
            end if
            if( ErrorDetected( "TCP" ) ) then
                err.description = RemoveDangerousCharacters( L_FAILEDTODISABLETCP_TEXT )
                g_bError = TRUE
                Exit Do
            end if
        end if

    Loop Until TRUE

    if ( FALSE = g_bError ) then
        Response.Redirect "../server_props.asp?server=" & g_strQueryStringServer & "&category=" & g_strCategory & "&pluginIndex=" & qs("pluginIndex")
    end if

elseif lcase( L_CONFIGUREELLIPSESBUTTON_TEXT ) = lcase( GetFormStr("op") ) then
    Response.Redirect "NetSourceProxy.asp?" & qs
end if

if( 0 = Len( strUdpPortRange ) ) then
    on error resume next
    bUdpEnabled = CBool( g_objPluginAdmin.UDPEnabled )
    dwNumRanges = CDbl( g_objPluginAdmin.NumUDPPortRanges )
    bUseUdpPorts = ( 0 = CDbl(g_objPluginAdmin.NumUDPPortRanges ) )
    for iEachRange = 0 to ( dwNumRanges - 1 )
        if( ( 0 = g_objPluginAdmin.UDPPortRangeLowerBound( iEachRange) ) or ( g_objPluginAdmin.UDPPortRangeLowerBound( iEachRange) = g_objPluginAdmin.UDPPortRangeUpperBound( iEachRange ) ) ) then
            strUdpPortRange = strUdpPortRange & g_objPluginAdmin.UDPPortRangeUpperBound( iEachRange )
        else
            strUdpPortRange = strUdpPortRange & CStr( g_objPluginAdmin.UDPPortRangeLowerBound( iEachRange )  ) & L_RANGEDELIMITER_TEXT & CStr( g_objPluginAdmin.UDPPortRangeUpperBound( iEachRange ) )
        end if
        if( iEachRange < ( dwNumRanges -1 ) ) then
            strUdpPortRange = strUdpPortRange & L_LISTDELIMITER_TEXT
        end if
    next
else
    bUdpEnabled = TRUE
    bUseUdpPorts = TRUE
    dwNumRanges = 1
    on error goto 0
end if

bTcpEnabled = g_objPluginAdmin.TCPEnabled


'////////////////////////////////////////////////////////////////////////////
'
' Parse upper and lower bounds from a substring
'
Function ProcessRange( strInput, byRef dwLowerBound, byRef dwUpperBound )
    on error goto 0
    ProcessRange = TRUE

    Dim dwOffsetToDash
    Dim rgCurrentRange
    Dim dwNumSubArrayEntries

    dwOffsetToDash = InStr( 1, strInput, L_RANGEDELIMITER_TEXT, vbTextCompare )

    if( ( Null = dwOffsetToDash ) or ( 0 = dwOffsetToDash ) ) then
'        on error resume next
        on error goto 0
        err.clear
        dwLowerBound = 0
        dwUpperBound = CDbl( strInput )

        if( 0 <> err.number ) then
            ProcessRange = FALSE
            Exit Function
        end if
    else
        rgCurrentRange = Split( strInput, "-", -1, 1 )
        dwNumSubArrayEntries = UBound( rgCurrentRange )

        if( 1 > dwNumSubArrayEntries ) then
            dwLowerBound = CDbl( rgCurrentRange( 0 ) )
            dwUpperBound = dwLowerBound
        else
            dwLowerBound = CDbl( rgCurrentRange( 0 ) )
            dwUpperBound = CDbl( rgCurrentRange( 1 ) )

            if( dwLowerBound = dwUpperBound ) then
                dwLowerBound = 0
            end if
        end if
    end if
End Function


'////////////////////////////////////////////////////////////////////////////
'
' Parse comma-delimited list for a set of ranges
'
Function SetRanges( strRanges )

    Dim bRetVal
    bRetVal = TRUE
    on error resume next

    Dim i
    Dim rgRanges
    Dim strCurrentRange
    Dim dwNumArrayEntries
    Dim dwLowerBound
    Dim dwUpperBound
    Dim dwOffsetToComma
    Dim bResult

    g_objPluginAdmin.DeleteAllUDPPortRanges

    ' Handle the base case
    dwOffsetToComma = InStr( 1, strRanges, L_LISTDELIMITER_TEXT, vbTextCompare )
    if( ( Null = dwOffsetToComma ) or ( 0 = dwOffsetToComma ) ) then

        bResult = ProcessRange( strRanges, dwLowerBound, dwUpperBound )

        if( 0 = err.number ) then
            Call g_objPluginAdmin.AddUDPPortRange( dwLowerBound, dwUpperBound )
            if( 0 <> err.number ) then
                bRetVal = FALSE
                g_bError = TRUE
                Session( "ErrorDescription" ) = Err.description
                Session( "ErrorNumber" ) = Err.Number
                Session( "ErrorCulprit" ) = "portRange"
                err.clear
            end if
        end if
        Exit Function

    else    ' process more than one range

        i = 0
        dwNumArrayEntries = 0
        rgRanges = Split( CStr( strRanges ), L_LISTDELIMITER_TEXT, -1, vbTextCompare )
        dwNumArrayEntries = UBound( rgRanges )

        For i = 0 to dwNumArrayEntries
            strCurrentRange = CStr( rgRanges( i ) )
            bResult = ProcessRange( strCurrentRange, dwLowerBound, dwUpperBound )

            if( ( TRUE = bResult ) and ( 0 = err.number ) ) then
                call g_objPluginAdmin.AddUDPPortRange( dwLowerBound, dwUpperBound )
                if( 0 <> err.number ) then
                    bRetVal = FALSE
                    g_bError = TRUE
                    Session( "ErrorDescription" ) = Err.description
                    Session( "ErrorNumber" ) = Err.Number
                    Session( "ErrorCulprit" ) = "portRange"
                    err.clear
                end if
            end if
        Next

    end if

    SetRanges = bRetVal
End Function

WriteHTMLHeader( g_strDecodedServerName )
%>
<link rel="stylesheet" type="text/css" href="<%= Session( "cssName" ) %>">
<% WritePluginJSUtils %>
<script language="JavaScript">
<!--
/*@cc_on @*/

var g_bAlertedUserToBadPort = false;

/////////////////////////////////////////////////////////////////////
function ContainsIllegalPortRangeChars( szPortRange )
{
    <% jsTRY %>
    // disregard white spaces
    szPortRange = szPortRange.replace( /(\s)+/g, "" );

    var lenPortRange = szPortRange.length;
    var szNewPortRange = szPortRange.replace( /[^\d,;\-]*/g, "" );
    if( szNewPortRange.length != lenPortRange )
    {
        return( true );
    }
    <% jsCATCH %>
    return( false );
}

/////////////////////////////////////////////////////////////////////
function PortListIsLegal( szPortRange )
{
    <% jsTRY %>
    // disregard white spaces
    szPortRange = szPortRange.replace( /(\s)+/g, "" );

    var regExpTest = new RegExp( /^(\d{1,5})([,;\-]?\d{1,5})*$/gi );
    if( ! regExpTest.test( szPortRange ) )
    {
        return( false );
    }
    return( true );

    <% jsCATCH %>
    return( false );
}

//////////////////////////////////////////////////////////////////////////
function ValidatePorts()
{
    <% jsTRY %>
        if( true == document.forms.pluginForm.portRange.disabled )
        {
            document.forms.pluginForm.ok.disabled = false;
            return;
        }

        var szRange = new String( document.forms.pluginForm.portRange.value );
        szRange = szRange.replace( /(\s)+/g, "" );
        if( 0 == szRange.length )
        {
            document.forms.pluginForm.ok.disabled = true;
            return;
        }

        if( ContainsIllegalPortRangeChars( szRange ) )
        {
            document.forms.pluginForm.ok.disabled = true;
            document.forms.pluginForm.portRange.style.color="#ff0000";
            if( ! g_bAlertedUserToBadPort )
            {
                g_bAlertedUserToBadPort = true;
                window.alert( "<%= L_TYPEMISMATCH_TEXT %>" );
            }
            window.status = "<%= L_TYPEMISMATCH_TEXT %>";
            return;
        }
        if( ! PortListIsLegal( szRange ) )
        {
            document.forms.pluginForm.ok.disabled = true;
//            document.forms.pluginForm.portRange.style.color="#ff0000";
            return;
        }
        document.forms.pluginForm.portRange.style.color="#000000";
        document.forms.pluginForm.ok.disabled = false;
        window.status = "";
    <% jsCATCH %>
}

//////////////////////////////////////////////////////////////////////////
function EnableUDPPorts()
{
    <% jsTRY %>
        if( ! document.forms.pluginForm.useUDP.checked )
        {
            document.forms.pluginForm.useUDP.checked = true;
        }

        if( ! document.forms.pluginForm.usePorts.checked )
        {
            document.forms.pluginForm.usePorts.checked = true;
        }
    <% jsCATCH %>
}


//////////////////////////////////////////////////////////////////////////
function ToggleUDPPorts( bSimulatedClick )
{
    <% jsTRY %>
        document.forms.pluginForm.ok.disabled = false;

        if( bSimulatedClick )
        {
            if( document.forms.pluginForm.useUDP.checked )
            {
                document.forms.pluginForm.usePorts.checked = ! document.forms.pluginForm.usePorts.checked;
            }
        }

        if( ! document.forms.pluginForm.useUDP.checked )
        {
            document.forms.pluginForm.usePorts.disabled = true;
            document.forms.pluginForm.portRange.disabled = true;
            <% if( brMSIE = g_dwBrowserType ) then %>
            portRangeLabel.disabled = true;
            <% end if %>

            szPorts = document.forms.pluginForm.portRange.value;
            if( 0 == szPorts.length )
            {
                document.forms.pluginForm.usePorts.checked = false;
            }

            return;
        }
        else
        {
            document.forms.pluginForm.usePorts.disabled = false;
            document.forms.pluginForm.portRange.disabled = false;
            <% if( brMSIE = g_dwBrowserType ) then %>
            portRangeLabel.disabled = false;
            <% end if %>
        }

        if( document.forms.pluginForm.usePorts.checked )
        {
            document.forms.pluginForm.usePorts.disabled = false;
            document.forms.pluginForm.portRange.disabled = false;
            <% if( brMSIE = g_dwBrowserType ) then %>
            portRangeLabel.disabled = false;
            <% end if %>
            document.forms.pluginForm.useUDP.checked = true;
            document.forms.pluginForm.portRange.focus();

            var szRange = new String( document.forms.pluginForm.portRange.value );
            if( 0 == szRange.length )
            {
                document.forms.pluginForm.ok.disabled = true;
            }
        }
        else
        {
            document.forms.pluginForm.portRange.disabled = true;
            <% if( brMSIE = g_dwBrowserType ) then %>
            portRangeLabel.disabled = true;
            <% end if %>
        }
    <% jsCATCH %>
}

//////////////////////////////////////////////////////////////////////////
function ToggleUDP( bSimulateClick )
{
    <% jsTRY %>
        if( bSimulateClick )
        {
            document.forms.pluginForm.useUDP.checked = ! document.forms.pluginForm.useUDP.checked;
        }

        if( document.forms.pluginForm.useUDP.checked )
        {
            document.forms.pluginForm.usePorts.disabled = false;
            document.forms.pluginForm.portRange.disabled = false;
            <% if( brMSIE = g_dwBrowserType ) then %>
            portRangeLabel.disabled = false;
            <% end if %>
        }
        else
        {
            document.forms.pluginForm.usePorts.disabled = true;
            document.forms.pluginForm.portRange.disabled = true;
            <% if( brMSIE = g_dwBrowserType ) then %>
            portRangeLabel.disabled = true;
            <% end if %>
        }

        ToggleUDPPorts( false );
    <% jsCATCH %>
}

//////////////////////////////////////////////////////////////////////////
function ToggleTCP( bSimulateClick )
{
    <% jsTRY %>
        if( bSimulateClick )
        {
            document.forms.pluginForm.useTCP.checked = ! document.forms.pluginForm.useTCP.checked;
        }
    <% jsCATCH %>
}

//////////////////////////////////////////////////////////////////////////
function ToggleTCPHTTP( bSimulateClick )
{
    <% jsTRY %>
        if( bSimulateClick )
        {
            if( ! document.forms.pluginForm.TCPHTTP.disabled )
            {
                document.forms.pluginForm.TCPHTTP.checked = ! document.forms.pluginForm.TCPHTTP.checked;
            }
        }
    <% jsCATCH %>
}

//////////////////////////////////////////////////////////////////////////
// always simulated
function ToggleProxyRadio( dwWhichButton )
{
    <% jsTRY %>
        var element;
        element = document.forms.pluginForm.protocolList[ dwWhichButton ];
        element.checked = true;
    <% jsCATCH %>
}

//////////////////////////////////////////////////////////////////////////
function GetCheckedProtocol()
{
    <% jsTRY %>
        var i;
        var e;

        //if length is defined, iterate over the elements
        if( document.forms.pluginForm.protocolList.length )
        {
            for( i = 0; i < document.forms.pluginForm.protocolList.length; i++ )
            {
                e = document.forms.pluginForm.protocolList[ i ];
                if ( e.checked )
                {
                    return e.value;
                }
            }
        //length isn't defined, so there's only the dummy element
        }
    <% jsCATCH %>
    return null;
}

//////////////////////////////////////////////////////////////////////////
function GetSelectedProtocol()
{
    <% jsTRY %>
        var i;
        var e;

        //if length is defined, iterate over the elements
        if(document.forms.pluginForm.protocolList)
        {
            for(i = 0; i < document.forms.pluginForm.protocolList.length; i++)
            {
                e = document.forms.pluginForm.protocolList[i];
                if (e.checked)
                {
                    return SafeEscape( e.value );
                }
            }
        //length isn't defined, so there's only the dummy element
        }
    <% jsCATCH %>
    return null;
}

//////////////////////////////////////////////////////////////////////////
function JumpToProxySettings()
{
    <% jsTRY %>
        var szProtocol, szUsePortRange, szPortRange, szUDP, szTCP;
        szProtocol = GetSelectedProtocol();

        szUsePortRange = new String( "" );
        if( document.forms.pluginForm.usePorts.checked )
        {
            szUsePortRange = "1";
        }
        else
        {
            szUsePortRange = "0";
        }

        szUDP = ( document.forms.pluginForm.useUDP.checked ) ? "1" : "0";
        szTCP = ( document.forms.pluginForm.useTCP.checked ) ? "1" : "0";

        szPortRange = new String( document.forms.pluginForm.portRange.value );

        document.location.replace( "NetSourceProxy.asp?server=<%= g_strQueryStringServer %>&pluginIndex=<%= qs("pluginIndex") %>&category=<%= g_strCategory %>&protocol=" + szProtocol + "&protocolList=" + szProtocol + "&usePortRange=" + szUsePortRange + "&portRange=" + szPortRange + "&useUDP=" + szUDP + "&useTCP=" + szTCP );
    <% jsCATCH %>
}
-->
</script>
</head>
<body class="pluginBody" onLoad="JavaScript:ToggleUDPPorts( false );ValidatePorts();" oncontextmenu="JavaScript:event.cancelBubble=true;return false;">
<% DrawPluginBanner %>
<table width="<%= Server.HTMLEncode( STDTABLEWIDTH ) %>">
<tr>
    <td valign=top>

        <% WriteStdPluginForm %>

        <table cellpadding=0 cellspacing=0 class="propgroupbox" width="100%">
        <caption align="left" class="pluginGroupHeader"><%= Server.HTMLEncode( L_PROTOCOLS_TEXT ) %></caption>
        <tr>
            <td colspan=4>
                <br> <%= Server.HTMLEncode( L_USESTREAMINGPROTOLS_TEXT ) %><br>
            </tr>
            <tr>
            <td>
            <br>
            <table width=99% align=center border=0 cellspacing=2 cellpadding=0>
                <tr>
                    <td colspan=3 ><% dwTabIndex = dwTabIndex + 1 %>
                        <input
                        type="checkbox"
                        name="useUDP"
                        ID="useUDP"
                        value="on"
                        tabindex=<%= dwTabIndex %> <%
                        if bUdpEnabled and ( 0 <> StrComp( qs( "useUDP" ), "0", vbTextCompare ) ) then
                            Response.Write( " checked" )
                        end if
                        %>
                        onClick="JavaScript:ToggleUDP( false );"
                        >
                        <label for="useUDP" class="handcursor">
                        <% RenderWithErrorCheck Server.HTMLEncode( L_UDPRTSP_TEXT ), "UDP" %></label>
                    </td>
                </tr>
                <tr>
                    <td width=10 > </td>
                    <td width=4% align=left > </td>
                    <td align=left nowrap><% dwTabIndex = dwTabIndex + 1 %>
                        <input
                        type="checkbox"
                        name="usePorts"
                        value="on"
                        ID="usePorts"
                        tabindex=<%= dwTabIndex %> <%
                            if( ( 0 < Len( strUdpPortRange ) ) and ( 0 <> StrComp( qs( "usePortRange" ), "0", vbTextCompare ) ) )then
                                Response.Write( " checked" )
                            end if %>
                        onClick="JavaScript:ToggleUDPPorts( false );"
                        >
                        <label nowrap for="usePorts" class="handcursor" ID="portRangeLabel" name="portRangeLabel">
                        <% RenderWithErrorCheck Server.HTMLEncode( L_DATAPORTS_TEXT ), "portRange" %></label>

                    </td>
                    <td align=left><% dwTabIndex = dwTabIndex + 1 %>
                        <input
                        type="text"
                        name="portRange"
                        size="40"
                        maxlength="255"
                        value="<%= RemoveSpecifiedChars( strUdpPortRange, REGEXP_DANGEROUS_CHARS ) %>"
                        tabindex=<%= dwTabIndex %>
                        onKeyDown="JavaScript:ValidatePorts();"
                        onKeyUp="JavaScript:ValidatePorts();"
                        onChange="JavaScript:EnableUDPPorts();ValidatePorts();"
                        onPaste="JavaScript:EnableUDPPorts();ValidatePorts();"
                        <% if ( 0 = Len( strUdpPortRange ) ) then
                            Response.Write( " disabled " )
                        end if %> > <br>
                    </td>
                    <td width=20% align=left > </td>
                    <td> </td>
                </tr>
                <tr>
                    <td colspan=3><% dwTabIndex = dwTabIndex + 1 %>
                        <input
                        type="checkbox"
                        name="useTCP"
                        ID="useTCP"
                        value="on"
                        tabindex=<%= dwTabIndex %> <%
                        if bTcpEnabled and ( 0 <> StrComp( qs( "useTCP" ), "0", vbTextCompare ) ) then
                            Response.Write( " checked" )
                        end if %>
                        onClick="JavaScript:ToggleTCP( false );">
                        <label for="useTCP" class="handcursor"><% RenderWithErrorCheck Server.HTMLEncode( L_TCP_TEXT ), "TCP" %></span><br>
                    </td>
                </tr>
            </table>
            </td>
        </tr>
        </table>
    </td>
</tr>
<tr>
    <td>
    <%
        if 0 < dwNumProtocols then
    %>
        <br>
        <table cellpadding=0 cellspacing=0 class="propgroupbox" width="100%">
        <caption align="left" class="pluginGroupHeader"><%= Server.HTMLEncode( L_PROXYSETTINGS_TEXT ) %></caption>
        <tr>
            <td colspan=4>
                <br> <%= Server.HTMLEncode( L_CONFIGUREPROTOCOL_TEXT ) %><br>
            </tr>
            <tr>
                <td width=5>

                </td>
                <td>
                    <table cellpadding=0 cellspacing=0 border=0 width=100%><tr><td>
                        <table cellpadding=0 cellspacing=0 border=1 bordercolor="silver" width=100% class="protocolTable">
                        <th class="colheader">
                              <%= Server.HTMLEncode( L_PROTOCOL_TEXT ) %>
                        </th>
                        <th class="colheader">
                              <%= Server.HTMLEncode( L_PROXY_TEXT ) %>
                        </th>
                        <tr>
                            <td colspan=2><img src="img/hr.gif" width=100% height=2></td>
                        </tr>

                        <%
                        Dim strProtocol
                        Dim strProxyHostName
                        Dim dwProxyPort
                        Dim bSomethingChecked
                        Dim displayedElement
                        Dim dwProxySetting

                        displayedElement = -1

                        bSomethingChecked = FALSE
                        for i = 0 to ( dwNumProtocols - 1 )
                            strProtocol = ""
                            strProxyHostName = ""

                            Err.Clear
                            strProtocol = g_objPluginAdmin.SupportedProtocolName( i )
                            dwProxySetting = g_objPluginAdmin.ProxySettings( strProtocol )
                            if( WMS_PROXY_SETTING_NONE = dwProxySetting ) then
                                strProxyHostName = CStr( "" )
                                dwProxyPort = CDbl( 0 )
                            else
                                strProxyHostName = g_objPluginAdmin.ProxyHostName( strProtocol )
                                dwProxyPort = g_objPluginAdmin.ProxyPort( strProtocol )
                            end if

                            if( "" = strProxyHostName ) then
                                strProxyHostName = L_NONE_TEXT
                            else
                                strProxyHostName = strProxyHostName & ":" & dwProxyPort
                            end if

                            if( 0 = err.number ) then
                                displayedElement = displayedElement + 1
                        %>
                        <tr bgcolor=ffffff>
                            <td>
                                <div
                                    class="small"
                                    onclick="JavaScript:ToggleProxyRadio( <%= displayedElement %> );/*JumpToProxySettings();*/">
                                <input <% dwTabIndex = dwTabIndex + 1 %>
                                  type="radio"
                                  name="protocolList"
                                  value="<%= Server.HTMLEncode( strProtocol ) %>"
                                  ID="<%= Server.HTMLEncode( strProtocol ) %>"  <%
                                if ( FALSE = bSomethingChecked ) and ( ( "" = GetPostOrQsVal("protocolList") ) or ( 0 = strcomp( strProtocol, GetPostOrQsVal("protocolList") ) ) ) then
                                    Response.Write( "checked" )
                                    bSomethingChecked = TRUE
                                end if
                                %> tabindex=<%= dwTabIndex %>> <label for="strProtocol" class="handcursor"><%= strProtocol %></label>
                                </div>
                            </td>
                            <td>
                                <div
                                    class="handcursor"
                                    onclick="JavaScript:ToggleProxyRadio( <%= displayedElement %> );JumpToProxySettings();">
                                      <%= Server.HTMLEncode( strProxyHostName ) %>
                                </div>
                            </td>
                        </tr>
                        <%
                            end if
                        next
                        %>
                        </table>
                        <tr>
                            <td> </td>
                            <td align=right>
                                <br><% dwTabIndex = dwTabIndex + 1 %>
                                <INPUT
                                    type="button"
                                    name="ProxySettings"
                                    onClick="JavaScript:JumpToProxySettings();"
                                    value="<%= Server.HTMLEncode( L_CONFIGUREELLIPSESBUTTON_TEXT ) %>"
                                    tabIndex=<%= dwTabIndex %>
                                >
                            </td>
                        </tr>
                    </table>
                    </td></tr></table>
                </td>
            </tr>
        </table>
        <% end if %>
    </td>
</tr>
<tr>
    <td>
        <tr>
            <td valign=bottom>
                <br><% dwTabIndex = dwTabIndex + 1 %>
                <input type="submit" align="baseline" name="ok"  tabIndex=<%= dwTabIndex %> value="<%= Server.HTMLEncode( L_OKAYBUTTON_TEXT ) %>" id="ok">
                <% dwTabIndex = dwTabIndex + 1 %>
                <input type="button" align="baseline" name="cancel" onclick="JavaScript:Cancel();" tabIndex=<%= dwTabIndex %> value="<%= Server.HTMLEncode( L_CANCELBUTTONSPACED_TEXT ) %>">
                <% dwTabIndex = dwTabIndex + 1 %>
                <input type="button" align="baseline" name="cancel" onclick="JavaScript:DoPluginHelp( '<%= H_NETSOURCETOPIC %>' );" tabIndex=<%= dwTabIndex %> value="<%= Server.HTMLEncode( L_HELPBUTTONSPACED_TEXT ) %>">
            </td>
        </tr>
    </td>
</tr>
</form>
</table>
<%
AlertUserWithPopupErrorDialog
err.clear
ClearError
DrawStdFooter
%>
</body>
</html>
<%
LatchCurrentPage "plugins/NetworkSource.asp", qs
EndErrorHandling "NetworkSource.asp"

on error resume next
PluginsASPCleanup
%>